Custom feature script for 2 extrudes

_anton said:

Do you need a feature that makes multiple extrudes in different directions? They'll all need their own end conditions, at which point it might be easier to just use multiple extrude features.

Else, can you share a simple example of what this feature would do that you'd normally do with multiple features?

If you do want to write a custom feature, a great way to start is by copying our Extrude feature from here into a Feature Studio and modifying it as needed.

MichaelPascoe said:

@KyleDarnell Welcome to FeatureScript!
Here are the general steps you will need to be able to do this:

https://cad.onshape.com/documents/82e1c77948a53493dda93e14/w/903175619ca8b00048792ef7/e/313a6c018bed8f931e1776a2

annotation { "Feature Type Name" : "Edge Prep" }
export const edgePrep = defineFeature(function(context is Context, id is Id, definition is map)
    precondition
    {
        // Define the parameters of the feature type
        
        // This is where your user interface goes
        
        annotation { "Name" : "Face", "Filter" : EntityType.FACE, "MaxNumberOfPicks" : 1 }
        definition.face is Query;
        
    }
    {
        // Define the function's action
        
        // Create a plane at the top right corner of the selected face
        const facePlane = evFaceTangentPlane(context, {
                "face" : definition.face,
                "parameter" : vector(1, 1) //This means that the plane will be at the top right corner 0,0 is the bottom left
        });
        
        // Create a plane on the right side 
        const sidePlane = plane(facePlane.origin, facePlane.x, -facePlane.normal);
        
        // Debug shows you items in the graphics area or in the monitor
        debug(context, facePlane, DebugColor.BLUE);
        debug(context, sidePlane, DebugColor.RED);
        
        // Sketch on the "frontPlane"
        var faceSketch = newSketchOnPlane(context, id + "sketchFacePlane", {
                "sketchPlane" : facePlane
        });
        
        skCircle(faceSketch, "circle1", {
                "center" : vector(0, 0) * inch,
                "radius" : 1 * inch
        });
        
        skSolve(faceSketch);
        
        // Find the sketch region from the sketch
        const faceSketchToExtrude = qSketchRegion(id + "sketchFacePlane");
        
        // Extrude the sketch
        opExtrude(context, id + "extrudeFaceSketch", {
                "entities" : faceSketchToExtrude,
                "direction" : -facePlane.normal,
                "endBound" : BoundingType.BLIND,
                "endDepth" : 0.25 * inch
        });
        
        // Find the extruded part
        const extrudedParts = qCreatedBy(id + "extrudeFaceSketch", EntityType.BODY);
        
        // Subtract parts
        opBoolean(context, id + "booleanRemoveFrontParts", {
                "tools" : extrudedParts,
                "targets" : qOwnerBody(definition.face),
                "operationType" : BooleanOperationType.SUBTRACTION
        });
    });