How to move a part using BodyType.MATE_CONNECTOR

@Fda

I am going to assume that what you want is to move the cylinder that you extruded to be build right on top of the mate connector?  If not, then I may need additional detail.  Instead of using a transform, I would just make the cylinder where you want it in the first place:

const mateConnectorCSys = evMateConnector(context, { "mateConnector" : definition.FaceConnector });
const mateConnectorAsPlane = plane(mateConnectorCsys);

const sketchId = id + "sketch";
var sketch = newSketchOnPlane(context, sketchId, mateConnectorAsPlane);
// Now we are sketching directly on the coordinate system defined by the mate connector
... 
do any sketching you want
...

// It is usually better to use opExtrude (operation) rather than extrude (feature).
const extrudeId = id + "extrude";
opExtrude(context, extrudeId, {
    "entities" : qSketchRegion(sketchId),
    "direction" : mateConnectorCSys.zAxis,
    "endBound" : BoundingType.BLIND,
    "endDepth" : 100 * millimeter
});

// Now delete the sketch and you should be done.

Just for the sake of completeness, if you do want to move something from one place to another, you could do it like this:

const moveFrom = coordSystem(vector(0, 0, 0) * inch, vector(1, 0, 0), vector(0, 0, 1)); // or any other coordinate system that you want to use as a "base"
const moveTo = evMateConnector(context, { "mateConnector" : definition.FaceConnector });
opTransform(context, id + "transform", {
    "bodies" : someQueryForBodiesToMove,
    "transform" : toWorld(moveTo) * fromWorld(moveFrom)
});

@Fda

First:
If you are moving parts "from" the selected mate connector "to" the origin, you'll have to switch "moveFrom" and "moveTo".  The mate connector is "moveFrom" and the origin is "moveTo".

Second:
The mate connector is not actually associated with the body that you clicked on to create it in any way that is easy to pull out of FeatureScript.

The most direct way to approach this would be to just add a:

annotation { "Name" : "Bodies to move", "Filter" : EntityType.BODY }
definition.bodiesToMove is Query;

to the precondition, and make your user select the bodies they want to move.

Another way of doing it which does not rely on the user selecting the bodies they want to move, but does rely on the mate connector touching the body, and may end up moving bodies that you don't want to move, could be the following:

const myBody = qContainsPoint(qConstructionFilter(qEverything(EntityType.BODY), ConstructionObject.NO), moveFrom.origin);

@Fda

You do not need both the `definition.bodiesToMove` and the `myBody = qContainsPoint(...)` code. As of right now, your `definition.bodiesToMove` parameter is not used anywhere, and does not do anything. 

Either take the bodies to move as a parameter, so that the user must click on the exact bodies they want to move:

annotation { "Feature Type Name" : "My Mate" }
export const myFeature = defineFeature(function(context is Context, id is Id, definition is map)
    precondition
    {
        // Define the parameters of the feature type
        annotation { "Name" : "Bodies to move", "Filter" : EntityType.BODY }
        definition.bodiesToMove is Query;
        
        annotation { "Name" : "My Query", "Filter" : BodyType.MATE_CONNECTOR  , "MaxNumberOfPicks" : 1 }
        definition.FaceConnector is Query;
    }
    {
        const moveFrom = coordSystem(vector(0, 0, 0) * inch, vector(1, 0, 0), vector(0, 0, 1)); // or any other coordinate system that you want to use as a "base"
        const moveTo = evMateConnector(context, { "mateConnector" : definition.FaceConnector });

        opTransform(context, id + "transform", {
                    "bodies" : definition.bodiesToMove,
                    "transform" : toWorld(moveTo) * fromWorld(moveFrom)
                });
    });

Or do not make the user select the bodies they want to move, and make an educated guess based on the position of the mate connector:

annotation { "Feature Type Name" : "My Mate" }
export const myFeature = defineFeature(function(context is Context, id is Id, definition is map)
    precondition
    {
        annotation { "Name" : "My Query", "Filter" : BodyType.MATE_CONNECTOR  , "MaxNumberOfPicks" : 1 }
        definition.FaceConnector is Query;
    }
    {
        const moveFrom = coordSystem(vector(0, 0, 0) * inch, vector(1, 0, 0), vector(0, 0, 1)); // or any other coordinate system that you want to use as a "base"
        const moveTo = evMateConnector(context, { "mateConnector" : definition.FaceConnector });

        const myBody = qContainsPoint(qConstructionFilter(qEverything(EntityType.BODY), ConstructionObject.NO), moveFrom.origin);

        opTransform(context, id + "transform", {
                    "bodies" : myBody,
                    "transform" : toWorld(moveTo) * fromWorld(moveFrom)
                });

    <span>});</span>