Rotate Mate Connector Button in Featurescript UI

HuguesLessardWRI

Is there a way to display and use the button shown on the picture below on the UI of a custom feature script to rotate a mate connector 90° increment?

kevin_o_toole_1

Actually this is definitely possible. A simple example:

FeatureScript 1204;
import(path : "onshape/std/geometry.fs", version : "1204.0");
export import(path : "onshape/std/mateconnectoraxistype.gen.fs", version : "1204.0");

annotation { "Feature Type Name" : "Rotate a thing" }
export const myFeature = defineFeature(function(context is Context, id is Id, definition is map)
    precondition
    {
        annotation { "Name" : "Thing", "Filter" : EntityType.BODY }
        definition.thing is Query;

        annotation { "Name" : "QuadRotationDirection", "UIHint" : "MATE_CONNECTOR_AXIS_TYPE", "Default" : MateConnectorAxisType.PLUS_X }
        definition.quadRotationDirection is MateConnectorAxisType;
    }
    {
        const rotationAmount is ValueWithUnits = {
             MateConnectorAxisType.PLUS_X : 0 * degree,
             MateConnectorAxisType.PLUS_Y : 90 * degree,
             MateConnectorAxisType.MINUS_X : 180 * degree,
             MateConnectorAxisType.MINUS_Y : 270 * degree,
        }[definition.quadRotationDirection];

        opTransform(context, id + "transform1", {
                "bodies" : definition.thing,
                "transform" : rotationAround(Z_AXIS, rotationAmount)
        });
    });

Example document

NeilCooke

Unfortunately, no. But you could use the circular arrow as shown in the Draft feature:

"UIHint" : "OPPOSITE_DIRECTION_CIRCULAR"

NeilCooke

You would have to include a hidden parameter in your predicate to store the value though, something like:

  annotation { "UIHint" : "ALWAYS_HIDDEN" }
  isInteger(definition.quadrant, POSITIVE_COUNT_BOUNDS);

kevin_o_toole_1

Actually this is definitely possible. A simple example:

FeatureScript 1204;
import(path : "onshape/std/geometry.fs", version : "1204.0");
export import(path : "onshape/std/mateconnectoraxistype.gen.fs", version : "1204.0");

annotation { "Feature Type Name" : "Rotate a thing" }
export const myFeature = defineFeature(function(context is Context, id is Id, definition is map)
    precondition
    {
        annotation { "Name" : "Thing", "Filter" : EntityType.BODY }
        definition.thing is Query;

        annotation { "Name" : "QuadRotationDirection", "UIHint" : "MATE_CONNECTOR_AXIS_TYPE", "Default" : MateConnectorAxisType.PLUS_X }
        definition.quadRotationDirection is MateConnectorAxisType;
    }
    {
        const rotationAmount is ValueWithUnits = {
             MateConnectorAxisType.PLUS_X : 0 * degree,
             MateConnectorAxisType.PLUS_Y : 90 * degree,
             MateConnectorAxisType.MINUS_X : 180 * degree,
             MateConnectorAxisType.MINUS_Y : 270 * degree,
        }[definition.quadRotationDirection];

        opTransform(context, id + "transform1", {
                "bodies" : definition.thing,
                "transform" : rotationAround(Z_AXIS, rotationAmount)
        });
    });

Example document

NeilCooke

@kevin_o_toole_1 - every day's a school day!