How do I create a plane that is perpendicular to a surface?

Answers

• _anton Member, Onshape Employees Posts: 510

  October 2021 Answer ✓

  If you have a planar face and you want to make *some* plane perpendicular to it, you can construct it with perpendicularVector(facePlane.normal) as the normal. https://cad.onshape.com/FsDoc/library.html#perpendicularVector-Vector
  

  1
• duncan_ledesma Member Posts: 6 ✭

  December 2025

  Testing using the TFR planes - perpendicularVector only works for Front "Cannot resolve plane". This is not a complete answer unfortunately.

  Here is my file if you're curious. It attempts to make a sketch given a face and extrudes a cylinder. The relevant portion is three lines long and comprises two println sandwiching the plane.normal reassignment:

  FeatureScript 2837;
  import(path : "onshape/std/common.fs", version : "2837.0");
  
  annotation { "Feature Type Name" : "Cylinder", "Feature Type Description" : "Make a cylinder in the middle of the plane" }
  export const f3 = defineFeature(function(context is Context, id is Id, definition is map)
      precondition
      {
          // Define the parameters of the feature type
          annotation { "Name": "Face", "Filter": EntityType.FACE }
          definition.face is Query;
          annotation { "Name" : "Diameter" }
          isLength(definition.diameter, LENGTH_BOUNDS);
          annotation { "Name" : "Length" }
          isLength(definition.length, LENGTH_BOUNDS);
          
      }
      {
          
          // Assertion
          if (definition.diameter <= 0 || definition.length <= 0) throw regenError("Absolute values only");
          
          // Face -> Plane
          var plane = evPlane(
              context, 
              { "face" : definition.face }
          );
          
          println("Before: " ~ plane.normal);
          plane.normal = perpendicularVector(plane.normal);  // uncomment this line to use original behaviour
          println("After: " ~ plane.normal);
          
          // Plane -> Sketch
          var sketch = newSketchOnPlane(
              context, 
              id + "sketch", 
              { "sketchPlane" : plane }
          );
          
          // Sketch -> Add circle 
          skCircle(sketch, "circle", {
                  "center" : vector(0, 0) * millimeter,
                  "radius" : definition.diameter,
          });
          
          skSolve(sketch);
          
          var skr = qSketchRegion(id + "sketch");
          
          opExtrude(context, id + "extrude", {
              "entities" : skr,
              "direction" : evOwnerSketchPlane(context, {"entity" : skr}).normal,
              "startBound": BoundingType.BLIND,
              "startDepth": definition.length / 2,
              "endBound" : BoundingType.BLIND,
              "endDepth" : definition.length / 2
          });   
      });
  

  If I learn of a solution that works for all test cases, I will come back to this thread.

  0
• NeilCooke Moderator, Onshape Employees Posts: 5,952

  December 2025

  You can't just change a plane's normal, you need to reconstruct it using plane(plane.origin, perpendicularVector(plane.normal))

  Senior Director, Technical Services, EMEA

  1
• duncan_ledesma Member Posts: 6 ✭

  January 1

  https://forum.onshape.com/discussion/comment/125001#Comment_125001

  Replying to confirm that this solved my issue. I spent a shameful amount of time trying to fix it in other ways the other day, but it's obvious even to a non-mathematician.

  1